18. Úlohy pro samostatnou práci IV

#include <Servo.h>

#define TLACITKO  14
#define LED_GREEN 18
#define LED_RED   19
#define SERVO     8

#define ZAVORA_DOLE   120
#define ZAVORA_NAHORE 50

#define PRODLEVA  5000
  
Servo servo;

void setup()   {                
  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(TLACITKO, INPUT_PULLUP);
  servo.attach(SERVO);
  servo.write(ZAVORA_DOLE);
}

void Semafor(bool x) {
  digitalWrite(LED_RED, !x);
  digitalWrite(LED_GREEN, x);
}

void loop()                     
{
  if (digitalRead(TLACITKO) == 0) {
    servo.write(ZAVORA_NAHORE);
    Semafor(1);
    delay(PRODLEVA);
    Semafor(0);
    servo.write(ZAVORA_DOLE);
  }
}

#include <Servo.h>

#define TLACITKO  14
#define LED_GREEN 18
#define LED_RED   19
#define SERVO     8

#define ZAVORA_DOLE   120
#define ZAVORA_NAHORE 50
#define ZAVORA_KROK   1 

#define PRODLEVA  5000
  
Servo servo;
word zavora_pozice = ZAVORA_DOLE;

void setup()   {                
  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(TLACITKO, INPUT_PULLUP);
  servo.attach(SERVO);
  servo.write(ZAVORA_DOLE);
}

void Semafor(bool x) {
  digitalWrite(LED_RED, !x);
  digitalWrite(LED_GREEN, x);
}

void Zavora(bool x) {
  if (x) {
    if (zavora_pozice > ZAVORA_NAHORE) zavora_pozice -= ZAVORA_KROK;
  } else {
    if (zavora_pozice < ZAVORA_DOLE) zavora_pozice += ZAVORA_KROK;
  }
  servo.write(zavora_pozice);
  delay(20);
} 

void loop()                     
{
  if (digitalRead(TLACITKO) == 0) {
    while (zavora_pozice != ZAVORA_NAHORE) Zavora(1);
    Semafor(1);
    delay(PRODLEVA);
    Semafor(0);
    while (zavora_pozice != ZAVORA_DOLE) Zavora(0);
  }
}

#include <Servo.h>

#define IR_LED    3
#define IR_PHOTO  A2
#define BUTTON    14
#define LED_GREEN 18
#define LED_RED   19
#define SERVO     8

#define ZAVORA_DOLE   120
#define ZAVORA_NAHORE 50
#define ZAVORA_KROK   1

#define PRODLEVA  2000

#define OBSAZENO  (obsazeno())
#define TLACITKO  (digitalRead(BUTTON) == 0)
#define NAHORE    (zavora_pozice == ZAVORA_NAHORE)
#define DOLE      (zavora_pozice == ZAVORA_DOLE)
  
Servo servo;
word zavora_pozice = ZAVORA_DOLE;

bool obsazeno() {
  digitalWrite(IR_LED, LOW);
  word zhasnuto = analogRead(IR_PHOTO);
  digitalWrite(IR_LED, HIGH);
  word rozsviceno = analogRead(IR_PHOTO);
  digitalWrite(IR_LED, LOW);
  return (zhasnuto - rozsviceno > 20);
}

void setup()   {                
  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(IR_LED, OUTPUT);
  pinMode(BUTTON, INPUT_PULLUP);
  servo.attach(SERVO);
  servo.write(ZAVORA_DOLE);
  delay(2000);
}

void Zavora(bool x) {
  if (x) {
    if (zavora_pozice > ZAVORA_NAHORE) zavora_pozice -= ZAVORA_KROK;
  } else {
    if (zavora_pozice < ZAVORA_DOLE) zavora_pozice += ZAVORA_KROK;
  }
  servo.write(zavora_pozice);
}

void Semafor(bool x) {
  digitalWrite(LED_RED, !x);
  digitalWrite(LED_GREEN, x);
}

bool TOV(bool x) {
  static uint32_t t;
  if (x) {
    return (millis() - t >= PRODLEVA);  
  } else {
    t = millis();
  }
  return 0;
}

bool TOF(bool x) {
  static uint32_t t;
  if (x) {
    t = millis();
    return 1;
  } else {
    return (millis() - t < PRODLEVA);  
  }
}

void loop()                     
{
  bool zavora = (OBSAZENO && !DOLE) || TLACITKO || (!NAHORE && zavora);
  bool semafor = NAHORE;

  Zavora(TOF(zavora));
  Semafor(semafor);
  
  delay(20);
}