12. Piezoměnič - aneb trocha muziky

#define BZUCAK    13
#define FREKVENCE 440
#define PRODLEVA  1000000/FREKVENCE/2

void setup()
{   
  pinMode(BZUCAK, OUTPUT);   
}

void loop()
{
  digitalWrite(BZUCAK, HIGH);  
  delayMicroseconds(PRODLEVA);
  digitalWrite(BZUCAK, LOW);   
  delayMicroseconds(PRODLEVA);
}

#define BZUCAK    13

void setup()
{   
  pinMode(BZUCAK, OUTPUT);   
}

void loop()
{
  int hodnota = analogRead(A1);
  if (hodnota > 0) {
    int frekvence = map(hodnota, 1, 1023, 100, 1000);
    tone(BZUCAK, frekvence);
  } else {
    noTone(BZUCAK);
  }
  delay(100);
}

#include "pitches.h" 

#define BZUCAK    13
#define TLACITKO3 16
#define TLACITKO4 17

#define TEMPO     8
#define OKTAVA    3

word _Tone[7][12] = {
  {NOTE_A1, NOTE_AS1, NOTE_B1, NOTE_C1, NOTE_CS1, NOTE_D1, NOTE_DS1, NOTE_E1, NOTE_F1, NOTE_FS1, NOTE_G1, NOTE_GS1},
  {NOTE_A2, NOTE_AS2, NOTE_B2, NOTE_C2, NOTE_CS2, NOTE_D2, NOTE_DS2, NOTE_E2, NOTE_F2, NOTE_FS2, NOTE_G2, NOTE_GS2},
  {NOTE_A3, NOTE_AS3, NOTE_B3, NOTE_C3, NOTE_CS3, NOTE_D3, NOTE_DS3, NOTE_E3, NOTE_F3, NOTE_FS3, NOTE_G3, NOTE_GS3},
  {NOTE_A4, NOTE_AS4, NOTE_B4, NOTE_C4, NOTE_CS4, NOTE_D4, NOTE_DS4, NOTE_E4, NOTE_F4, NOTE_FS4, NOTE_G4, NOTE_GS4},
  {NOTE_A5, NOTE_AS5, NOTE_B5, NOTE_C5, NOTE_CS5, NOTE_D5, NOTE_DS5, NOTE_E5, NOTE_F5, NOTE_FS5, NOTE_G5, NOTE_GS5},
  {NOTE_A6, NOTE_AS6, NOTE_B6, NOTE_C6, NOTE_CS6, NOTE_D6, NOTE_DS6, NOTE_E6, NOTE_F6, NOTE_FS6, NOTE_G6, NOTE_GS6},
  {NOTE_A7, NOTE_AS7, NOTE_B7, NOTE_C7, NOTE_CS7, NOTE_D7, NOTE_DS7, NOTE_E7, NOTE_F7, NOTE_FS7, NOTE_G7, NOTE_GS7}
}; 

word _Duration[] = {
  DURATION_32, DURATION_16, DURATION_16h, DURATION_8,
  DURATION_8h, DURATION_4, DURATION_4h, DURATION_2,
  DURATION_2h, DURATION_1
};

byte _Notes[] = {
  0, 2, 3, 5, 7, 8, 10
};

// Delka generovaneho tonu
//  0    1    2     3   4    5   6    7   8   9
// 1/32 1/16 1/16. 1/8 1/8. 1/4 1/4. 1/2 1/2. 1

char STAR_WARS[] = 
  "T8O4 \
   D3D3D3 \
   G7+D7 +C3B3A3+G7+D5 +C3B3A3+G7+D5 +C3B3+C3A7D5D3 \
   G7+D7 +C3B3A3+G7+D5 +C3B3A3+G7+D5 +C3B3+C3A7D5D3 \
   E8E3+C3B3A3G3 G3A3B3A5E3#F5D5D3 E8E3+C3B3A3G3 +D5A7D5D3 \
   E8E3+C3B3A3G3 G3A3B3A5E3#F5+D5+D3 +G3+F3+#D3+D3+C3#A3A3G3 +D8D3D3D3 \
   G7+D7 +C3B3A3+G7+D5 +C3B3A3+G7+D5 +C3B3+C3A5D5D3 \
   G7+D7 +C3B3A3+G7+D5 +C3B3A3+G7+D5 +C3B3+C3A7+D5 \
   +G9 +G8+G3+G3+G3 +G3R3R5R7 \
";

char IMPERIAL_MARCH[] = 
  "T8O3 \
  A5A5A5F3+C3 A5F3+C3A7 +E5+E5+E5+F3+C3 #G5F3+C3A7 \
  +A5A3A3+A5+#G3+G3 +#F3+F3+#F3#A3+#D5+D3+#C3 +C3B3+C3F3#G5F3#G3 +C5A3+C3+E7 \
  +A5A3A3+A5+#G3+G3 +#F3+F3+#F3#A3+#D5+D3+#C3 +C3B3+C3F3#G5F3+#C3 +A5F3+C3+A7 \
  \
  A5A5A5F3+C3 A5F3+C3A7 +E5+E5+E5+F3+C3 #G5F3+C3A7 \
  +A5A3A3+A5+#G3+G3 +#F3+F3+#F3#A3+#D5+D3+#C3 +C3B3+C3F3#G5F3+#C3 +A5F3+C3+A7 \
  +A5A3A3+A5+#G3+G3 +#F3+F3+#F3#A3+#D5+D3+#C3 +C3B3+C3F3#G5F3+#C3 +A5F3+C3+A7 \
  \
  E5F3D3+C5B3G3 +E5+#D3B3 +D3+C3#G3F3 E5F3D3+C5B3#G3 +A5+E3+C3#A3F3#C3-B3 \
  E5F3D3+C5B3G3 +E5+#D3B3 +D3+C3#G3F3 E5F3D3+C5B3#G3 +A5+E3+C3#A3F3#C3-#A3 \
";

char POPCORN[] = 
  "T8O3 \
  R7A3G3 A3E3C3E3 -A3R3A3G3 A3E3C3E3 -A3R3A3B3 +C3B3+C3A3 \
  B3A3B3G3 A3C3A3F3 A3R3A3G3 A3E3C3E3 -A3R3A3G3 \
  A3E3C3E3 -A3R3A3B3 +C3B3+C3A3 B3A3B3G3 A3G3A3B3 +C3R3+E3+D3 \
  +E3+C3G3+C3 E3R3+E3+D3 +E3+C3G3+C3 E3R3+E3+#F3 +G3+#F3+G3+E3 \
  +#F3+E3+#F3+D3 +E3+D3+E3C3 +E3R3+E3+D3 \
  +E3+C3G3+C3 E3R3+E3+D3 +E3+C3G3+C3 E3R3+E3+#F3 +G3+#F3+G3+E3 \
  +#F3+E3+#F3+D3 +E3+D3+E3C3 +E3R7R3 R9 \
";

/*
//  +#F3+E3+#F3+D3 +E3+D3+B3D3 +E3R3A3G3 \


  */
void setup()
{   
  pinMode(BZUCAK, OUTPUT);   
  pinMode(TLACITKO3, INPUT_PULLUP);
  pinMode(TLACITKO4, INPUT_PULLUP);
}

char* ptr = ""; 
byte tempo, oktava;

void playStart(char* _song) {
  ptr = _song;
  tempo = TEMPO;
  oktava = OKTAVA;
}

void playStop() {
  ptr = "";  
}

void play() {
  
  while (*ptr == ' ') ptr++;
  if (*ptr) {
    
    byte nota, _oktava = oktava;
    byte prefix = *ptr++;
    word ton = 0;

    if (prefix == 'O')  {
      oktava = *ptr++ - '0';
    } else if (prefix == 'T')  {
      tempo = *ptr++ - '0';
    } else {
      
      if (prefix != 'R')  {
        while (prefix == '+') {
          _oktava++;
          prefix = *ptr++;
        }
        while (prefix == '-') {
          _oktava--;
          prefix = *ptr++;
        }
  
        if (prefix == '#')
          nota   = _Notes[*ptr++ - 'A'] + 1;
        else
          nota   = _Notes[prefix - 'A'];
    
        ton = _Tone[_oktava][nota];
      }
  
      word delka  = _Duration[(*ptr++)-'1'] * tempo; 
     
      if (ton != 0) {
        tone(BZUCAK, ton);
      } else {
        noTone(BZUCAK);    
      }
      delay(delka);
      noTone(BZUCAK);
      delay(1);
    }
  }
}

void loop()
{
  if (digitalRead(TLACITKO3) == 0) {
    playStart(STAR_WARS);
  }
  if (digitalRead(TLACITKO4) == 0) {
//    playStart(IMPERIAL_MARCH);
    playStart(POPCORN);
  }

  play();
}